Setting Queue Tree Mikrotik Terbaik

Bagi kalian para pecinta mikrotik yang ingin melakukan managemen bandwith queue tree baik untuk warnet, jaringan rt rw net, perkantoran, kedai wifi dan lain-lainnya, berikut ini kami akan uraikan sedikit tutorial tentang limit bandwith dengan mode Queue Tree di Mikrotik routerOS.

Setting Queue Tree ini, bandwith akan dibagi rata untuk semua klien tetapi untuk browsing dan game menjadi jalur priority (prioritas).


Setting Queue Tree Mikrotik Terbaik


Setting priority untuk jalur browsing dan game ini dimaksudkan supaya klien yang sedang browsing dan bermain game online tidak terganggu ketika ada klien lain yang sedang download dan streaming youtube dan video lainnya.

Setting Queue Tree Mikrotik v6.x

Artikel yang kita bahas kali ini tentang setting queue tree akan kita terapkan pada Mikrotik routerOS versi 6.x. Jadi apabila mikrotik routerOS kalian masih menggunakan versi dibawahnya, silahkan lakukan upgrade Mikrotik routerOS terlebih dahulu.

Baca juga : Port Mobile Legend dan Game Online Mikrotik Terbaru 2020

Selanjutnya topologi jaringan dari Mikrotik routerOS yang akan kita setting Queue Tree kurang lebih seperti pada gambar dibawah ini:


Sebagaimana topologi diatas, kita kondisikan posisi ether1 terhubung ke internet ISP, dan ether2 terhubung ke jaringa LAN.

1. Setting Mangle


Selanjutnya kita akan melakukan setting mangle queue tree. Silahkan login me Mikrotik Routerbord kalian dan buka menu Terminal. Copy script dibawah ini:

/ip firewall address-list
add address=192.168.0.0/16 list=private_IPv4
add address=172.16.0.0/12 list=private_IPv4
add address=10.0.0.0/8 list=private_IPv4
/ip firewall layer7-protocol
add name=EXE regexp="\\x4d\\x5a(\\x90\\x03|\\x50\\x02)\\x04"
add name=ZIP regexp="pk\\x03\\x04\\x14"
add name=MP4 regexp="\\x18\\x66\\x74\\x79\\x70"
add name=RAR regexp="Rar\\x21\\x1a\\x07"
add name=youtube regexp="r[0-9]+---[a-z]+-+[a-z0-9-]+\\.googlevideo\\.com"
/ip firewall mangle
add action=accept chain=prerouting comment="Bypass Local Traffic" dst-address-list=private_IPv4 src-address-list=private_IPv4
add action=accept chain=forward dst-address-list=private_IPv4 src-address-list=private_IPv4
add action=mark-connection chain=forward comment="Games Traffic" dst-port=39190-39200 new-connection-mark=games passthrough=yes protocol=tcp src-address-list=private_IPv4
add action=mark-connection chain=forward dst-port=40000-40010 new-connection-mark=games passthrough=yes protocol=udp src-address-list=private_IPv4
add action=mark-packet chain=forward connection-mark=games in-interface="ether1 - Wan" new-packet-mark=games_down passthrough=no
add action=mark-packet chain=forward connection-mark=games in-interface="ether2 - Lan" new-packet-mark=games_up passthrough=no
add action=mark-connection chain=forward comment="ICMP Traffic" new-connection-mark=icmp passthrough=yes protocol=icmp src-address-list=private_IPv4
add action=mark-packet chain=forward connection-mark=icmp in-interface="ether1 - Wan" new-packet-mark=icmp_down passthrough=no protocol=icmp
add action=mark-packet chain=forward connection-mark=icmp in-interface="ether2 - Lan" new-packet-mark=icmp_up passthrough=no protocol=icmp
add action=mark-connection chain=forward comment="DNS Traffic" dst-port=53 new-connection-mark=dns passthrough=yes protocol=udp src-address-list=private_IPv4
add action=mark-packet chain=forward connection-mark=dns in-interface="ether1 - Wan" new-packet-mark=dns_down passthrough=no protocol=udp
add action=mark-packet chain=forward connection-mark=dns in-interface="ether2 - Lan" new-packet-mark=dns_up passthrough=no protocol=udp
add action=mark-connection chain=forward comment="Remote Traffic" dst-port=22,23,8291,5938,4899 new-connection-mark=remote passthrough=yes protocol=tcp src-address-list=private_IPv4
add action=mark-packet chain=forward connection-mark=remote in-interface="ether1 - Wan" new-packet-mark=remote_down passthrough=no
add action=mark-packet chain=forward connection-mark=remote in-interface="ether2 - Lan" new-packet-mark=remote_up passthrough=no
add action=mark-connection chain=forward comment="YouTube Traffic" layer7-protocol=youtube new-connection-mark=youtube passthrough=yes src-address-list=private_IPv4
add action=mark-packet chain=forward connection-mark=youtube in-interface="ether1 - Wan" new-packet-mark=youtube_down passthrough=no
add action=mark-packet chain=forward connection-mark=youtube in-interface="ether2 - Lan" new-packet-mark=youtube_up passthrough=no
add action=mark-connection chain=forward comment="Extension Layer7" layer7-protocol=EXE new-connection-mark=extensi passthrough=yes
add action=mark-connection chain=forward layer7-protocol=ZIP new-connection-mark=extensi passthrough=yes
add action=mark-connection chain=forward layer7-protocol=MP3 new-connection-mark=extensi passthrough=yes
add action=mark-connection chain=forward layer7-protocol=RAR new-connection-mark=extensi passthrough=yes
add action=mark-packet chain=forward connection-mark=extensi in-interface="ether1 - Wan" new-packet-mark=extensi_down passthrough=no
add action=mark-packet chain=forward connection-mark=extensi in-interface="ether2 - Lan" new-packet-mark=extensi_up passthrough=no
add action=mark-connection chain=forward comment="Browsing Traffic" connection-mark=!heavy_traffic new-connection-mark=browsing passthrough=yes src-address-list=private_IPv4
add action=mark-connection chain=forward comment="Heavy Traffic" connection-bytes=1024000-0 connection-mark=browsing connection-rate=256k-102400k new-connection-mark=heavy_traffic passthrough=yes protocol=tcp
add action=mark-connection chain=forward connection-bytes=1024000-0 connection-mark=browsing connection-rate=256k-102400k new-connection-mark=heavy_traffic passthrough=yes protocol=udp
add action=mark-packet chain=forward connection-mark=heavy_traffic in-interface="ether1 - Wan" new-packet-mark=heavy_browsing_down passthrough=no
add action=mark-packet chain=forward connection-mark=heavy_traffic in-interface="ether2 - Lan" new-packet-mark=heavy_browsing_up passthrough=no
add action=mark-packet chain=forward connection-mark=browsing in-interface="ether1 - Wan" new-packet-mark=small_browsing_down passthrough=no
add action=mark-packet chain=forward connection-mark=browsing in-interface="ether2 - Lan" new-packet-mark=small_browsing_up passthrough=no
Keterangan:
ether1 - Wan : merupakan interface ether1 yang terhubung ke internet ISP
ether2 - Lan : merupakan interface ether2 yang terhubung ke jaringan LAN

Baca juga : Cara Setting Mikrotik Dasar Lengkap Dengan Winbox

2. Setting Queue Tree


Setelah setting mangle sudah kita lakukan, selanjutnya kita akan setting queue tree, silahkan copy kode script dibawah ini dan pastekan ke jendela terminal Mikrotik routerOS kalian.

/queue type
add kind=pcq name=down_pcq pcq-classifier=dst-address pcq-dst-address6-mask=64 pcq-src-address6-mask=64
add kind=pcq name=up_pcq pcq-classifier=src-address pcq-dst-address6-mask=64 pcq-src-address6-mask=64
/queue tree
add name="Global Traffic" parent=global queue=default
add max-limit=3M name=Download parent="Global Traffic" queue=default
add max-limit=1M name=Upload parent="Global Traffic"
add limit-at=512k max-limit=3M name="1. Game" packet-mark=games_down parent=Download priority=1 queue=down_pcq
add limit-at=64k max-limit=3M name="2. Icmp" packet-mark=icmp_down parent=Download priority=1 queue=down_pcq
add limit-at=64k max-limit=3M name="3. Dns" packet-mark=dns_down parent=Download priority=1 queue=down_pcq
add max-limit=3M name="5. Download Traffic" parent=Download queue=default
add max-limit=3M name="1. Small Browsing" packet-mark=small_browsing_down parent="5. Download Traffic" priority=5 queue=down_pcq
add max-limit=3M name="2. Heavy Browsing" packet-mark=heavy_browsing_down parent="5. Download Traffic" priority=7 queue=down_pcq
add limit-at=512k max-limit=3M name="4. Remote" packet-mark=remote_down parent=Download priority=3 queue=down_pcq
add max-limit=3M name="3. YouTube" packet-mark=youtube_down parent="5. Download Traffic" priority=7 queue=down_pcq
add max-limit=3M name="4. Extensi" packet-mark=extensi_down parent="5. Download Traffic" queue=down_pcq
add limit-at=256k max-limit=1M name="1. game" packet-mark=games_up parent=Upload priority=1 queue=up_pcq
add limit-at=32k max-limit=1M name="2. icmp" packet-mark=icmp_up parent=Upload priority=1 queue=up_pcq
add limit-at=32k max-limit=1M name="3. dns" packet-mark=dns_up parent=Upload priority=1 queue=up_pcq
add limit-at=256k max-limit=1M name="4. remote" packet-mark=remote_up parent=Upload priority=3 queue=up_pcq
add max-limit=1M name="5. Upload Traffic" parent=Upload queue=default
add max-limit=1M name="1. small browsing" packet-mark=small_browsing_up parent="5. Upload Traffic" priority=5 queue=up_pcq
add max-limit=1M name="2. heavy browsing" packet-mark=heavy_browsing_up parent="5. Upload Traffic" priority=7 queue=up_pcq
add max-limit=1M name="3. youtube" packet-mark=youtube_up parent="5. Upload Traffic" priority=7 queue=up_pcq
add max-limit=1M name="4. extensi" packet-mark=extensi_up parent="5. Upload Traffic" queue=up_pcq
Jika sudah berhasil dilakukan, akan didapati tampilan jendela queue tree mikrotik routerOS kita sebagai berikut:


Hal penting yang menjadi catatan disini adalah, artikel ini hanya sebagai contoh atau referensi cara melakukan setting bandwith queue tree mikrotik routerOS yang pada umumnya banyak dipakai di jaringa rt rw net, perkantoran bahkan lebih-lebih di Cafe atau jaringan Wifi publik. Akan tetapi, settingan diatas tidaklah mengikat, tinggal bagaimana kita menyesuaikan dengan kebutuhan masing-masing klien.

Kesimpulannya adalah dengan melakukan setting bandwith dengan queue tree di mikrotik ini, kita melakukan pemisahan jalur akses dari browsing, game, download dan streaming. Khusus browsing dan game online akan diberi akses prioritas supaya stabil, sedangkan untuk download dan streaming diberika limit yang sesuai dan dipakai bersama-sama sehingga tidak menggangu jalur akses yang melakukan browsing maupun game online.

Baca juga :
Konfigurasi DHCP Server Mikrotik Mudah dengan Winbox
Setting Hotspot Mikrotik Mudah dengan Winbox


Demikianlah artikel kali ini tentang Setting Queue Tree Mikrotik Terbaik, semoga bermanfaat. Selamat mencoba

Iklan Atas Artikel

Iklan Tengah Artikel 1

Iklan Tengah Artikel 2

Iklan Bawah Artikel